批处理重命名特殊文件名的代码

 更新时间:2010年10月11日 08:11:10   转载 作者:  
文件夹下有三个由字母、数字、汉字、特殊字符组成文件名的文件同时批处理自身也在其中。
一b!a!1235@_ s%#8i 三 c.rar
h^e12 0~%l%!p!@. s321-的文件.txt
%o%%% !O!ffi9~ ce$- Wor8d29 文档.docx
重命名.bat
图1:

要求运行批处理将这三个文件文件名中的数字、汉字、特殊字符全部(含空格)去掉,而重命名为只含字母的文件,但
后缀名不能更改,同时批处理自身名字不能更改,重命名后:
basic.rar
helps.txt
oOfficeWor.docx
重命名.bat
图2:

要求:代码简洁、通用、效率不至于太低。
pusofalse:
复制代码 代码如下:

@echo off
for %%a in (*.*) do (
if "%%~nxa" neq "%~nx0" (
set "name=%%~na"
setlocal enabledelayedexpansion
set name1=!name!
call :lp
ren "!name!%%~xa" "!nam!%%~xa"
set "nam="
endlocal
)
)
pause
:lp
if defined name1 (
set "var=!name1:~,1!"
if "!var!" leq "Z" (
if "!var!" geq "a" (
set "nam=!nam!!var!"
))
set "name1=!name1:~1!"
goto lp
)

 

batman:
复制代码 代码如下:

@echo off
set "code=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for /f "delims=" %%a in ('dir /s /a-d /b') do (
if "%%~nxa" neq "重命名.bat" (
set "str=%%~na"&set "file=%%a"&set "var=%%~na"
setlocal enabledelayedexpansion
for %%i in (%code%) do set "str=!str:%%i=!"
set "str=!str: =!"&call :lp
ren "!file!" !files!%%~xa
endlocal
))
goto :eof
:lp
set /a n+=1
for /f "tokens=%n% delims=%str% " %%a in ("%var%") do (
if "%%a" neq "" set "files=!files!%%a"&goto lp
)

描述下整体思路吧:

大家看到了题中的文件名是由字母+数字+特殊字符+汉字组成的,看起来很复杂,但我们是不是可以换个角度这样看:文件名是由分隔符+字母组成的(将数字、特殊字符、汉字全看成分隔符),是不是简单多了,呵呵,麻烦的还在后面。。。
那么,我们又遇到问题了:数字、特殊字符还好说数量是有限的,汉字可是个麻烦事啊,我们总不能在delims=后面把所有汉字全写上吧(况且这个长度是有限的)?这是不可能的,怎么办呢?于是,我们可以先将文件名中不是字母的字符全提出来,怎么提?这就要用到变量替换了,将26个字母全替换为空。
有人会说了效率有问题,这里确实存在效率问题,但大家想一下比较逐字符的判断的效率这个还是要高一点,为什么?假设一个文件名有十几个a,用逐字符就要判断十几次,而变量替换只一次就搞定了。
经过这样替换后的字符串中是不是只留下了不是字母的字符。现在只要把其来做为分隔符(别忘了加上空格)来提取文件名中的所有的字母了,而剩下的工作就只是技术处理了。

dishuo:

根据 pusofalse斑竹的思路,提取字符最方便的工具肯定是正则表达式,批处理命令唯一一个支持正则的就是findstr,能不能用它来提取呢?
测试成功!
满足要求:简洁、通用、效率不至于太低。
特点:通用性很强,只需要修改 findstr 的正则参数就能实现各种功能,举几个例子。
   "[^-!-~0-9a-z]" 保留全角字符(中文、全角标点等)
   "[a-z0-9]"   保留英文字母和数字
复制代码 代码如下:

@echo off&cls
for /f "tokens=*" %%i in ('dir /b/a-d "*.*"') do (
if "%%~nxsi" neq "%~nxs0" (
set "旧文件名=%%~nxsi"&set "文件名串=%%~ni"&set "新文件名="&set "counter=0"
del ~filenamechar.lst /q>nul 2>&1
setlocal enabledelayedexpansion
call :split
for /f "tokens=*" %%n in ('findstr "[a-z]" ~filenamechar.lst') do set "新文件名=!新文件名!%%n"
if "!新文件名!" neq "" (
echo ren !旧文件名! !新文件名!%%~xi
) else (
echo ^(文件"!旧文件名!"不含字母,不能重命名.^)
)
endlocal
)
)
del ~filenamechar.lst /q>nul 2>&1
pause&goto :eof

:split
if "!文件名串:~%counter%,1!" neq "" (
if "!文件名串:~%counter%,1!" neq " " echo !文件名串:~%counter%,1!>>~filenamechar.lst
set /a counter+=1
goto split
)
goto :eof

相关文章

最新评论