script_tool_for_windows.bat Windows 环境下的 hosts 一键部署脚本

 更新时间:2016年04月17日 16:31:22   投稿:mdxy-dxy  
这篇文章主要介绍了script_tool_for_windows.bat Windows 环境下的 hosts 一键部署脚本,需要的朋友可以参考下

我们提供了一系列工具让您除了手动以 复制/粘贴 的方式部署和更新 hosts 之外,有一种方便、一键式的方式来应用我们的 hosts 。

我们现有的工具可以在下列平台上工作:
Microsoft Windows (.bat script; Qt GUI tool; console (service type) tool)

另外,我们还推荐使用跨平台的 Hozz 来管理、自动更新 hosts 。

目前,我们共有:

Hozz: 跨平台的 hosts 自动 管理/更新 工具。是 @ppoffice 的项目。

项目主页
项目Github主页 https://github.com/racaljk/hosts/tree/master/hosts_tools
HostTool: Windows 环境下的 hosts 自动更新应用,使用 C++ 构建, GUI 基于 Qt 。由 @racaljk 贡献。
HostToolforMac: Mac 环境下的 hosts 自动部署更新应用(适用于 OS X 10.10 或以上),基于 Swift 开发。由 @ZzzM 贡献。
HostsToolforWindows: Windows console环境下的 hosts 自动更新应用(作为系统服务),使用 C++ 构建。由 @Too-Naive 贡献。
script_tool_for_windows.bat: Windows 环境下的 hosts 一键部署脚本,由 @redapple0204 与 @lizongzeshunshun 贡献。以及 @lideming 提供的重要更新。

@echo off
if defined converted goto :converted

set ConverterPath=%temp%\HostsGeter_CodeConverter.vbs
set ConverterOutput=%temp%\HostsGeter_GBK.bat

echo inputpath="%~0" >%ConverterPath%
echo outputpath="%ConverterOutput%" >>%ConverterPath%
echo set stm2=createobject("ADODB.Stream") >>%ConverterPath%
echo stm2.Charset ="utf-8" >>%ConverterPath%
echo stm2.Open >>%ConverterPath%
echo stm2.LoadFromFile inputpath >>%ConverterPath%
echo readfile = stm2.ReadText >>%ConverterPath%
echo stm2.Close >>%ConverterPath%
echo Set Stm1 =CreateObject("ADODB.Stream") >>%ConverterPath%
echo Stm1.Type = 2 >>%ConverterPath%
echo Stm1.Open >>%ConverterPath%
echo Stm1.Charset ="GBK" >>%ConverterPath%
echo Stm1.Position = Stm1.Size >>%ConverterPath%
echo Stm1.WriteText "set converted=y" ^& vbcrlf >>%ConverterPath%
echo Stm1.WriteText readfile >>%ConverterPath%
echo Stm1.SaveToFile outputpath,2 >>%ConverterPath%
echo Stm1.Close >>%ConverterPath%
%ConverterPath% && %ConverterOutput%
goto :eof

:converted

chcp 936
:: 更改cmd窗口代码页至 936(GBK)

cls
%1 %2
ver|find " 5.">nul &&goto :st
echo 正在进行 UAC 提权...
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :st","","runas",1)(window.close)&goto :eof
:st

cls

@REM HostsGet Version0.4
cd /d %~dp0

set LogFilePath=%temp%\HostsGeter_log.txt
set DLScriptPath=%temp%\downloadhosts.vbs
set DLPath=%windir%\system32\drivers\etc\hosts_downloaded
set BackupDir=%windir%\system32\drivers\etc
set HostsPath=%windir%\system32\drivers\etc\hosts

set LogToFile=^>^>%LogFilePath% 2^>^&1
set EchoAndLog=call :echoandlog
echo. %LogToFile%
echo ==========[%date% %time%]========== %LogToFile%
echo 日志文件:
echo %LogFilePath%
echo.

echo iLocal=LCase("%DLPath%") > %DLScriptPath% ||(
 call :error downloadhosts.vbs 文件创建/写入失败.
)
echo iRemote=LCase("https://raw.githubusercontent.com/racaljk/hosts/master/hosts") >> %DLScriptPath%
echo Set xPost=createObject("Microsoft.XMLHTTP") 'Set Post = CreateObject("Msxml2.XMLHTTP") >> %DLScriptPath%
echo xPost.Open "GET",iRemote,0 >> %DLScriptPath%
echo xPost.Send() >> %DLScriptPath%
echo set sGet=createObject("ADODB.Stream") >> %DLScriptPath%
echo sGet.Mode=3 >> %DLScriptPath%
echo sGet.Type=1 >> %DLScriptPath%
echo sGet.Open() >> %DLScriptPath%
echo sGet.Write xPost.ResponseBody >> %DLScriptPath%
echo sGet.SaveToFile iLocal,2 >> %DLScriptPath%

%EchoAndLog% 开始从 GitHub 中下载 hosts 文件...
if exist %DLPath% del %DLPath% /s /q %LogToFile%
%DLScriptPath% || call :error hosts 文件下载失败.
del %DLScriptPath% /s /q %LogToFile%
if not exist %DLPath% call :error hosts 文件下载失败.
%EchoAndLog% 下载完成.
echo.

if exist %HostsPath% (
  call :backuphosts
) else (
  %EchoAndLog% (原 hosts 文件不存在,跳过备份)
)
%EchoAndLog% 正在替换 hosts 文件...
move %DLPath% %HostsPath% %LogToFile% || call :error hosts 文件替换失败.
%EchoAndLog% hosts 文件已替换.
echo.

%EchoAndLog% 正在刷新系统 DNS 缓存...
ipconfig /flushdns %LogToFile% || call :error DNS 缓存刷新失败.
%EchoAndLog% DNS 缓存已刷新.
echo.
%EchoAndLog% 【操作全部完成!】
echo.

echo 按任意键访问 google.com.hk 进行测试,如取消,请直接关闭本窗口
pause >nul
start https://www.google.com.hk
echo 已经帮你访问 google.com.hk 如可以访问则替换成功.
echo.
goto :end

:backuphosts
%EchoAndLog% 正在备份原 hosts 文件...
set "bakfilename=hosts_%date%_%time:~0,8%.bak"
set bakfilename=%bakfilename:/=-%
set bakfilename=%bakfilename:\=-%
set bakfilename=%bakfilename::=-%
set bakfilename=%bakfilename: =_%
copy %HostsPath% %BackupDir%\%bakfilename% %LogToFile% || call :error hosts 文件备份失败.
%EchoAndLog% 原 hosts 文件已备份到 %BackupDir%\%bakfilename%.
echo.
goto :eof

:error
echo ======================
%EchoAndLog% 错误:%*
start %LogFilePath%
echo 已打开日志文件
goto :end

:echoandlog
echo %*
echo %* %LogToFile%
goto :eof

:end
echo 按任意键关闭
pause >nul
exit

相关文章

  • DOS下常用的20个基本操作命令

    DOS下常用的20个基本操作命令

    DOS命令总共大约有一百个(包括文本编辑、查杀病毒、配置文件、批处理等)常用的也就是为数不多的一二十个,我们就介绍常用的DOS命令
    2023-10-10
  • 命令行窗口自动居中之批处理版实现代码(娱乐)

    命令行窗口自动居中之批处理版实现代码(娱乐)

    这篇文章主要介绍了命令行窗口自动居中之批处理版实现代码(娱乐),需要的朋友可以参考下
    2023-07-07
  • windows下通过批处理快速批量更换IP方法

    windows下通过批处理快速批量更换IP方法

    windows快速批处理更换IP方法适合于经常更换IP或者配置大量服务器IP,平时基本手动配置就好了,这里仅供大姐学习交流,windows快速批处理更换IP代码如下
    2013-09-09
  • 使用批处理重置TCP_IP协议

    使用批处理重置TCP_IP协议

    因某种情况我们需要重新安装TCP/IP协议来解决一些问题的话,我们可以通过下面的批处理来完成,需要的朋友可以参考下
    2013-11-11
  • bat 传递超过10个参数的情况

    bat 传递超过10个参数的情况

    批处理文件中可引用的参数为%0~%9, %0是指批处理文件的本身,也可以说是一个外部命令;%1~%9是批处理参数,也称形参;而替换形参的实参若超过了批处理文件中所规定数值(9个)且想在批处理文件中应用这些实参的话,shift命令可以帮你实现
    2014-06-06
  • DOS窗口命令和单表简单查询

    DOS窗口命令和单表简单查询

    这篇文章主要介绍了DOS窗口命令和单表简单查询,主要包括相关术语和简单查询语句,本文给大家介绍的非常详细,对大家的学习或工作具有一定的参考借鉴价值,需要的朋友可以参考下
    2022-10-10
  • 批处理命令 BAT备份MySQL数据库

    批处理命令 BAT备份MySQL数据库

    MySQL数据的备份工具也许有很多,在这我要给大家分享一下通过DOS批处理命令和MySQL、WinRAR命令来进行备份工作。
    2009-07-07
  • 批处理+Rar实现批量独立压缩目录和解压目录

    批处理+Rar实现批量独立压缩目录和解压目录

    一把情况下,如果当前目录较多想分别压缩,如果一个一个的压缩肯定受不了,不妨用下面的代码试试。
    2010-03-03
  • bat批处理彻底隐藏文件的方法(使用虚拟磁盘实现)

    bat批处理彻底隐藏文件的方法(使用虚拟磁盘实现)

    这篇文章主要介绍了bat批处理彻底隐藏文件的方法,本文使用创建虚拟磁盘的方法实现,虚拟磁盘的盘符定为X盘,会出现在我的电脑中,使用时显示,不用时隐藏
    2014-06-06
  • 批处理bat删除指定天数日期之前的文件

    批处理bat删除指定天数日期之前的文件

    这篇文章主要介绍了通过批处理bat删除指定天数日期之前文件的实现代码,需要的朋友可以参考下
    2014-07-07

最新评论