脚本之家 服务器常用软件
快捷导航
您的位置：首页 → 网络编程 → JavaScript → javascript技巧 →

日期函数扩展类Ver0.1.1

 更新时间：2006年09月07日 00:00:00   作者：  

复制代码 代码如下:

<%
'转发时请保留此声明信息,这段声明不并会影响你的速度!
'**************************   【日期扩展类】Ver 0.1.1********************************
'开发人:        Sman、Net Fetch
'开发日期:        2005-11-11
'版本号:        Ver 0.1.1

'官方网站:http://www.sman.cn     http://www.ad0.cn
'电子邮件:huihui3030@126.com    NetFetchStudio@163.com  
'每日在线QQ:19341293             32050450
'版权声明:版权没有,盗版不究,源码公开,欢迎盗版,欢迎你到官方网站来寻求支持。
'如有任何改进之处，麻烦转发或者反馈一份到 huihui3030@126.com、NetFetchStudio@163.com，Thanks!
'详细使用说明或范例请见下载附件或到官方站点或Email联系下载！
'************************************************************************************

Class DateFunEx

    Private d_
    Private firstweekofyear_
    Private firstdayofweek_

    Private Sub class_initialize()
        d_                     = date() '默认当前日期
        firstdayofweek_     = 2    'vbMonday
        firstweekofyear_     = 1    '由 1 月 1 日所在的星期开始。
    End Sub

    '属性 setDate 日期
    Public Property Let setDate(value) 
        On Error Resume Next
        If IsNumeric(value) Then
            value = Cint(value)
            If len(value)< 3 Then value = "20" & right("0"&value,2)
            value = value & "-1" 
        End If 
        d_ = cDate(value)
    End Property

    '属性 firstweekofyear 每年的第一周(详细设置请参照VBS手册)
    Public Property Let firstweekofyear(value)
        firstweekofyear_ = cInt(value)
    End Property

    '属性 FirstDayofWeek 每周的第一天(详细设置请参照VBS手册)
    Public Property Let firstdayofweek(value)
        firstdayofweek_ = cInt(value)
    End Property


    '------------------------------
    ' 功能说明:算第几周的星期几是几号
    ' 参数说明:y 年,w周,week 星期 (星期一1 星期天7)
    '------------------------------
    Public Function GetWeekDate(y, w, DayofWeek)
        Dim NewYearDay
        NewYearDay = CDate(y & "-1-1") '元旦
        GetWeekDate = ((NewYearDay - Weekday(NewYearDay, firstdayofweek_)) + (w - 1) * 7 + DayofWeek)
    End Function

    '------------------------------
    ' 功能说明:获得某年某月的天数
    '------------------------------
    Public Function GetMonthDayCount()
        GetMonthDayCount = DateDiff("d", d_, DateAdd("m", 1, d_))
    End Function

    '------------------------------
    ' 功能说明:得到某年某月的第一天
    '------------------------------
    Public Function GetMonthFirstDay()
        GetMonthFirstDay = CDate( Year(d_) & "-" & Month(d_) & "-1")
    End Function

    '------------------------------
    ' 功能说明:得到某年的某月的最后一天
    '------------------------------
    Public Function GetMonthLastDay()
        GetMonthLastDay = CDate( Year(d_) & "-"&Month(d_) & "-" & DateDiff("d", d_, DateAdd("m", 1, d_)))
    End Function

    '------------------------------
    ' 功能说明:某日所在的周的第一天的日期
    '------------------------------
    Public Function WeekFirstDay()
        WeekFirstDay = GetWeekDate(Year(d_), DatePart("ww", d_,firstdayofweek_,firstweekofyear_), 1)
    End Function

    '------------------------------
    ' 功能说明:某日所在的周的第最后一天的日期
    '------------------------------
    Public Function WeekLastDay()
        WeekLastDay = GetWeekDate(Year(d_), DatePart("ww", d_,firstdayofweek_,firstweekofyear_), 7)
    End Function

End Class
%>

使用方法
复制代码 代码如下:

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<% Option Explicit %>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<title>Test_clsDateFunEx</title>
</head>

<body>
<!--#include file="clsDateFunEx.asp" -->
<%
Dim myDateFun,strDate 
strDate = "2005-4-1"
Set myDateFun = new DateFunEx 
    myDateFun.setDate = strDate
    Response.write "2006年第2周的星期一是几号:" & _
                         myDateFun.GetWeekDate(2006,2,1) &"<br>"
    Response.Write "2005年4月的天数:"&_
                         myDateFun.GetMonthDayCount & "<br>"
    Response.Write "2005年4月的第一天:"&_
                         myDateFun.GetMonthFirstDay & "<br>"
    Response.Write "2005年4月的最后一天:"&_
                         myDateFun.GetMonthLastDay & "<br>"
    Response.Write "2005年4月1日所在的周的第一天的日期:"&_
                         myDateFun.WeekFirstDay & "<br>"
    Response.Write "2005年4月1日所在的周的第最后一天的日期:" & _
                        myDateFun.WeekLastDay & "<br>"
Set myDateFun = Nothing
%>
<br><br><br>
</body>
</html>

相关文章

  • JS如何在字符串指定位置插入字符串

    JS如何在字符串指定位置插入字符串

    文章介绍了JavaScript中如何在字符串的指定位置插入字符串,主要通过`slice`方法来实现,`slice`方法可以根据起始和结束索引来提取字符串的一部分,文章还补充说明了如何在字符串的指定位置插入字符串,以及提供了相关代码示例
    2025-01-01
  • javascript图片滑动效果实现

    javascript图片滑动效果实现

    这篇文章主要介绍了超实用的javascript图片滑动效果实现方法,实例分析了javascript通过对页面元素与相关属性的操作实现滑动菜单效果的相关技巧，具有一定参考借鉴价值，需要的朋友可以参考下
    2015-11-11
  • layui时间控件选择时间范围的实现方法

    layui时间控件选择时间范围的实现方法

    今天小编就为大家分享一篇layui时间控件选择时间范围的实现方法，具有很好的参考价值，希望对大家有所帮助。一起跟随小编过来看看吧
    2019-09-09
  • js生成验证码并直接在前端判断

    js生成验证码并直接在前端判断

    众所周知，js是客户端的，那么把验证都做在客户端有意义吗？还是必须从服务器生成的验证码安全啊？前端生成的验证码安全吗？x下面我们来看个例子
    2015-05-05
  • 原生JS分页展示效果（点击分页看效果）

    原生JS分页展示效果（点击分页看效果）

    特别酷的分页展示效果，原生JS实现，点击分页看效果
    2012-11-11
  • 微信小程序中的数据存储实现方式

    微信小程序中的数据存储实现方式

    这篇文章主要介绍了微信小程序中的数据存储实现方式，文中通过示例代码介绍的非常详细，对大家的学习或者工作具有一定的参考学习价值，需要的朋友们下面随着小编来一起学习学习吧
    2021-08-08
  • JS模拟简易滚动条效果代码(附demo源码)

    JS模拟简易滚动条效果代码(附demo源码)

    这篇文章主要介绍了JS模拟简易滚动条效果代码,可模拟出滚动条拖动显示的效果,涉及JavaScript鼠标事件的响应及页面元素运算的相关技巧,并附带demo源码供读者下载参考,需要的朋友可以参考下
    2016-04-04
  • 原生JS使用Canvas实现拖拽式绘图功能

    原生JS使用Canvas实现拖拽式绘图功能

    这篇文章主要介绍了原生js实现Canvas实现拖拽式绘图，支持画笔、线条、箭头、三角形和圆形等等图形绘制功能,本文通过实例代码给大家介绍的非常详细，需要的朋友可以参考下
    2019-06-06
  • JS实现的A*寻路算法详解

    JS实现的A*寻路算法详解

    这篇文章主要介绍了JS实现的A*寻路算法,结合实例形式详细分析了A*寻路算法的概念、原理、实现技巧与相关注意事项,需要的朋友可以参考下
    2018-12-12
  • await/async无法捕获与处理错误信息的解决方案分享

    await/async无法捕获与处理错误信息的解决方案分享

    async await 中添加错误处理个人认为是有必要的,下面这篇文章主要给大家介绍了关于await/async无法捕获与处理错误信息的解决方案,文中通过实例代码介绍的非常详细,需要的朋友可以参考下
    2023-02-02

最新评论