函数说明

GUICtrlCreateSlider

在GUI上创建一个滑动条（Slider）控件。

GUICtrlCreateSlider ( 左侧, 上方 [, 宽度 [, 高度 [, 风格 [, 扩展风格]]]] )

参数

left	控件左侧的位置。若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置。
上方	控件上方的位置。若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置。
宽度	[可选参数] 控件的宽度（默认值为上一个控件的宽度）。
高度	[可选参数] 控件的高度（默认值为上一个控件的高度）。
风格	[可选参数] 指定控件的风格。请查看附录中关于 GUI 控件风格的说明。默认值（-1）：$TBS_AUTOTICKS
扩展风格	[可选参数] 指定控件的扩展风格。请查看附录的扩展风格表。

返回值

成功：	返回控件标识符（控件ID）。
失败：	返回值为0。

注意

若要获得控件的各种值请查看 GUICtrlRead.
若要设置或修改控件的各种信息请查看 GUICtrlSet....

若要更新滑块的位置请使用 GUICtrlSetData。
若要设置最小值和最大值请使用 GUICtrlSetLimit。

要在默认风格的基础上添加一个新的风格可使用 BitOr($GUI_SS_DEFAULT_SLIDER, 新风格,...)。

示例

#include <GUIConstants.au3>

GUICreate("slider",220,100, 100,200)
GUISetBkColor (0x00E0FFFF) ; 更改背景颜色

$slider1 = GUICtrlCreateSlider (10,10,200,20)
GUICtrlSetLimit(-1,200,0) ; 修改最小值/最大值
$button = GUICtrlCreateButton ("Value?",75,70,70,20)
GUISetState()
GUICtrlSetData($slider1,45) ; 设置滑块的初始位置

$start=TimerInit()
Do
  $n = GUIGetMsg ()

   If $n = $button Then
      MsgBox(0,"slider1",GUICtrlRead($slider1),2)
   $start=TimerInit()
   EndIf
Until $n = $GUI_EVENT_CLOSE