在GUI上创建一个标签页（Tab）控件。
GUICtrlCreateTab ( 左侧, 上方 [, 宽度 [, 高度 [, 风格 [, 扩展风格]]]] )
参数
| left | 控件左侧的位置。若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置。 |
| 上方 | 控件上方的位置。若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置。 |
| 宽度 | [可选参数] 控件的宽度（默认值为上一个控件的宽度）。 |
| 高度 | [可选参数] 控件的高度（默认值为上一个控件的高度）。 |
| 风格 | [可选参数] 指定控件的风格。请查看附录中关于 GUI 控件风格 的说明。 默认值（-1）：非强制性风格：$WS_TABSTOP, $WS_CLIPSIBLINGS |
| 扩展风格 | [可选参数] 指定控件的扩展风格。请查看附录的 扩展风格表。 |
返回值
| 成功： | 返回控件标识符（控件ID）。 |
| 失败： | 返回值为0。 |
注意
本函数只是创建了一个标签控件（容器），我们要在其中创建标签项，之后还要使用 GUICtrlCreate 来创建每个标签项的关联控件。
相关
GUICtrlCreateTabItem, GUICoordMode（选项）, GUICtrlSet..., GUIGetMsg
示例
#include <GUIConstants.au3>
GUICreate("我的 GUI 之Tab") ; 创建一个居中显示的窗口
GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)
$tab=GUICtrlCreateTab (10,10, 200,100)
$tab0=GUICtrlCreateTabitem ("tab0")
GUICtrlCreateLabel ("label0", 30,80,50,20)
$tab0OK=GUICtrlCreateButton ("OK0", 20,50,50,20)
$tab0input=GUICtrlCreateInput ("默认文本", 80,50,70,20)
$tab1=GUICtrlCreateTabitem ( "tab----1")
GUICtrlCreateLabel ("label1", 30,80,50,20)
$tab1combo=GUICtrlCreateCombo ("", 20,50,60,40)
GUICtrlSetData(-1,"Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; 默认是 Jon
$tab1OK=GUICtrlCreateButton ("OK1", 80,50,50,20)
$tab2=GUICtrlCreateTabitem ("tab2")
GUICtrlSetState(-1,$GUI_SHOW) ; 这个标签将先显示
GUICtrlCreateLabel ("label2", 30,80,50,20)
$tab2OK=GUICtrlCreateButton ("OK2", 140,50,50)
GUICtrlCreateTabitem ("") ; 结束标签项的定义
GUICtrlCreateLabel ("label3", 20,130,50,20)
GUISetState ()
; 运行脚本直到窗口被关闭
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend