设置某个控件的大小调整方式。
GUICtrlSetResizing ( 控件ID, 调整方式 )
参数
| 控件ID | 控件标识符（控件ID），可由 GUICtrlCreate... 函数的返回值获得。 |
| 调整方式 | 请查看下面的 停靠值列表 了解可用数值（可按需把相应数值相加）。 |
返回值
| 成功： | 返回值为1。 |
| 失败： | 返回值为0。 |
注意
当 GUI 窗口被调整大小时，其所属控件也会有相应变化，至于如何变化则是由本函数定义的。若要使某个 GUI 窗口可调整大小必须在创建时添加 $WS_SIZEBOX 和 $WS_SYSMENU 风格。请查看 GUICreate。| 调整方式 | 值 | 停靠位置 |
| $GUI_DOCKLEFT | 2 | 左边 |
| $GUI_DOCKRIGHT | 4 | 右边 |
| $GUI_DOCKHCENTER | 8 | 水平居中 |
| $GUI_DOCKTOP | 32 | 上方 |
| $GUI_DOCKBOTTOM | 64 | 底部 |
| $GUI_DOCKVCENTER | 128 | 垂直居中 |
| $GUI_DOCKWIDTH | 256 | 宽度不变 |
| $GUI_DOCKHEIGHT | 512 | 高度不变 |
| $GUI_DOCKSIZE | 768 | 大小不变（256+512=768） |
| $GUI_DOCKMENUBAR | 544 | 512+32=544，表示控件将保持在窗口上方并且高度不变 |
| $GUI_DOCKSTATEBAR | 576 | 512+64=576，表示控件将保持在窗口底部并且高度不变 |
| $GUI_DOCKALL | 802 | 2+32+256+512=802，表示（在窗口被调整大小时）控件位置将一直不变 |
相关
无
示例
#include <GUIConstants.au3>
Opt("GUICoordMode", 2)
GUICreate ("My InputBox",190,114,-1,-1,$WS_SIZEBOX+$WS_SYSMENU) ; 开始定义
GUISetIcon ("Eiffel Tower.ico")
GUISetFont (8,-1,"Arial")
GUICtrlCreateLabel ("提示", 8,7) ; 添加提示信息
GUICtrlSetResizing (-1,$GUI_DOCKLEFT+$GUI_DOCKTOP)
$nEdit = GUICtrlCreateInput ("Default", -1,3,175,20,$ES_PASSWORD) ; 添加输入框
GUICtrlSetState ($nEdit,$GUI_FOCUS)
GUICtrlSetResizing ($nEdit,$GUI_DOCKBOTTOM+$GUI_DOCKHEIGHT)
$nOk = GUICtrlCreateButton ("确定",-1,3,75,24) ; 添加按钮
GUICtrlSetResizing ($nOk,$GUI_DOCKBOTTOM+$GUI_DOCKSIZE+$GUI_DOCKVCENTER)
$nCancel = GUICtrlCreateButton ("取消", 25,-1) ; 添加按钮
GUICtrlSetResizing ($nCancel,$GUI_DOCKBOTTOM+$GUI_DOCKSIZE+$GUI_DOCKVCENTER)
GUISetState () ; 显示 GUI 窗口
; 运行脚本直到窗口被关闭
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend