函数说明

_viGTL

转到本地模式：接收到此命令的设备将退出“远程控制模式”而转为“本地模式”。若设备已经是“本地模式”则此命令将被忽略。通常来说，如果某个设备不支持此命令则在使用此命令后它将仍然保持在原有的“远程控制模式”。

#include <Visa.au3>
_viGTL($h_session)

参数

$h_session

VISA 描述符（字符串）或者 VISA session 句柄（整数）。
（请查看 _viExecCommand 函数的注意部分以了解更多信息）

返回值

成功： - 返回值为0
失败： - 返回值为 -1，说明无法打开 VISA DLL，否则为一个非零的数值，用以表示 VISA 错误码（请查看 VISA 编程人员指引）。
一旦出现错误则本函数将总是把 @error 设为 1

注意

所有的 VISA 函数都要求必须安装 VISA 库（您可以通过检查 WINDOWS\system32 目录下是否存在 visa32.dll 来判断）和一个 GPIB 卡（例如 National Instruments（美国国家仪器有限公司）的 NI PCI-GPIB 卡或者是 Agilent 82350B PCI 高性能 GPIB 卡）。

* 更详细的通用 VISA 描述符（DESCRIPTOR）请查看 _viExecCommand 函数的帮助部分。

示例

;- 这个脚本假定您已经把 GPIB 的地址设为 3
; 如果您的设备使用的是不同的地址，请把 "GPIB::3::0" 改为
; 相应的描述符。_viOpen 函数也是同样处理
; 本脚本演示了如何使用 _viGTL 函数以及 VISA 描述符、
; VISA 设备句柄的使用方法。首先我们要使用 _viExecCommand 函数来强制使设备跳到
; “远程模式”

#include <Visa.au3>

Dim $h_session = 0

; 请求设备的 GPIB 地址3 的 ID
MsgBox(0,"Step 1","Simple GPIB query using a VISA Descriptor")
Dim $s_answer = _viExecCommand("GPIB::3::0","*IDN?",10)
MsgBox(0,"GPIB QUERY result",$s_answer) ; 显示结果

MsgBox(0,"Step 2","Go to LOCAL using VISA Descriptor")
_viGTL("GPIB::1::0") ; 跳到本地模式（退出远程控制模式）

MsgBox(0,"Step 4","Open the instrument connection with _viOpen")
Dim $h_instr = _viOpen(3)
MsgBox(0,"Instrument Handle obtained", "$h_instr = " & $h_instr) ; 显示 Session 句柄
; 请求设备响应

MsgBox(0,"Step 5","Query the instrument using the VISA instrument handle")
$s_answer = _viExecCommand($h_instr,"*IDN?") ; 注意，$h_instr 现在已不再是字符串了！
MsgBox(0,"GPIB QUERY result",$s_answer) ; 显示结果
; 再次请求。这时不需要再次打开连接了

MsgBox(0,"Step 6","Query again. There is no need to OPEN the link again")
$s_answer = _viExecCommand($h_instr,"*IDN?")
MsgBox(0,"GPIB QUERY result",$s_answer) ; 显示结果

MsgBox(0,"Step 7","Go to LOCAL using VISA instrument handle")
_viGTL($h_instr); 跳到本地模式（可选）

MsgBox(0,"Step 8","Close the Instrument connection using _viClose")
_viClose($h_instr) ; 关闭设备连接