基 础 函 数 参 考

GUICtrlCreateAvi

创建 AVI 视频控件.

GUICtrlCreateAvi ( 文件名, 子文件, 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文件名 视频文件名. 仅支持 .avi 格式文件.
子文件 子文件 ID. 若该文件只有一个视频, 则设置为 0.
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 (-1) : $ACS_TRANSPARENT
除非指定 $ACS_NONTRANSPARENT, 否则总是使用 $ACS_TRANSPARENT.
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回新的控件标识符 (控件 ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

要在控件被创建后立即播放该视频剪辑,则添加 $ACS_AUTOPLAY 样式.
使用 GUICtrlSetState设置状态值为 1 或 0, 即可播放或停止视频剪辑. 请看示例.

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_AVI, 新样式,...) 语句.

使用上面列出的值必须将 #include <AVIConstants.au3> 语句写入脚本中.

默认大小为 $GUI_DOCKSIZE.

相 关 函 数

GUICoordMode (option), GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $ani1, $buttonstart, $buttonstop, $msg

    GUICreate("我的动画 GUI", 360, 200)
    $ani1 = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 50, 10)

    $buttonstart = GUICtrlCreateButton("启动动画", 80, 150, 70, 22)
    $buttonstop = GUICtrlCreateButton("停止动画", 180, 150, 70, 22)

    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    While 1
        $msg = GUIGetMsg()

        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop

            Case $msg = $buttonstart
                GUICtrlSetState($ani1, 1)

            Case $msg = $buttonstop
                GUICtrlSetState($ani1, 0)

        EndSelect
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)