基 础 函 数 参 考

GUICtrlCreateButton

创建按钮(Button)控件.

GUICtrlCreateButton ( "文本", 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文本 按钮控件显示的文本.
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度 (默认文本自动调整适合宽度).
高度 [可选参数] 控件的高度 (默认文本自动调整适合高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认 ( -1) : 无.
强制样式 : $WS_TABSTOP
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

设置或者修改控件信息, 参考 GUICtrlUpdate....

使用 $BS_ICON 或 $BS_BITMAP 样式即可让按钮显示图标或图片. 使用 GUICtrlSetImage 指定图片文件.

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_BUTTON, 新样式,...) 语句.

使用上面列出的值必须将 #include <ButtonConstants.au3> 语句写入脚本中.

默认大小为 $GUI_DOCKSIZE

相 关 函 数

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $Button_1, $Button_2, $msg
    GUICreate("我的按钮 GUI") ; 创建居中显示的 GUI 窗口

    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("运行记事本程序", 10, 30, 100)
    $Button_2 = GUICtrlCreateButton("测试", 0, -1)

    GUISetState() ; 显示有两个按钮的对话框

    ; 运行 GUI, 直到 GUI 被关闭
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $Button_1
                Run('Notepad.exe') ; 将运行并打开记事本程序
            Case $msg = $Button_2
                MsgBox(0, '测试', '你点击了 [ 测试 ] 按钮') ; 将显示 [ 测试 ] 按钮被按下的通知消息
        EndSelect
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)