基 础 函 数 参 考

GUICtrlCreateDate

创建日期控件.

GUICtrlCreateDate ( "文本", 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文本 预选的日期.(总是为 "yyyy/mm/dd" 格式).
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 (-1) : $DTS_LONGDATEFORMAT
强制样式 : $WS_TABSTOP
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.
默认扩展样式 (-1) : WS_EX_CLIENTEDGE

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_DATE, 新样式,...) 语句.

要格式化日期/时间, 请查看例子 3 了解怎么使用 GuiCtrlSendMsg 与 $DTM_SETFORMAT.

使用上面列出的值必须将 #include <DateTimeConstants.au3> 语句写入脚本中.

默认大小 $GUI_DOCKHEIGHT.

相 关 函 数

GUICoordMode (Option), GUICtrlSetState, GUIGetMsg, GUICtrlRead

函 数 示 例


#include <GUIConstantsEx.au3>
#include <DateTimeConstants.au3>

Example1()
Example2()
Example3()
Example4()

; 示例 1
Func Example1()
    Local $date, $msg

    GUICreate("获取日期 GUI", 200, 200, 800, 200)
    $date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)
    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(0, "日期", GUICtrlRead($date))
    GUIDelete()
EndFunc   ;==>Example1

; 示例 2
Func Example2()
    Local $n, $msg

    GUICreate("获取日期 GUI", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 10, 10, 100, 20, $DTS_SHORTDATEFORMAT)
    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(0, "日期", GUICtrlRead($n))
    GUIDelete()
EndFunc   ;==>Example2

; 示例 3
Func Example3()
    Local $date, $DTM_SETFORMAT_, $style

    GUICreate("获取日期 GUI", 200, 200, 800, 200)
    $date = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20)

    ; 设置默认日期时间格式
    $DTM_SETFORMAT_ = 0x1032 ; $DTM_SETFORMATW
    $style = "yyyy/MM/dd HH:mm:ss"
    GUICtrlSendMsg($date, $DTM_SETFORMAT_, 0, $style)

    GUISetState()
    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    MsgBox(0, "时间", GUICtrlRead($date))
EndFunc   ;==>Example3

; 示例 4
Func Example4()
    Local $n, $msg

    GUICreate("获取时间 GUI", 200, 200, 800, 200)
    $n = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    MsgBox(0, "时间", GUICtrlRead($n))
    GUIDelete()
EndFunc   ;==>Example4

provider with jb51.net (unicode)