基 础 函 数 参 考

GUICtrlCreateListViewItem

创建 ListView 控件的项目.

GUICtrlCreateListViewItem ( "文本", 控件 ID )

参 数

文本 由 Opt("GUIDataSeparatorChar") 设置分隔符分隔的项目文本.
控件 ID ListView 控件标识符.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

函数创建 ListView 控件中可供选择的项目. 项目可以由 GUICtrlSetData 设置数据.
如其它控件一样, 项目可由 GUICtrlDelete 删除.
ListView 项目可以拖放到具有 $GUI_DROPACCEPTED 状态的编辑或输入控件.
关于列的大小调整查看 GUICtrlCreateListView.

特定标志 $GUI_BKCOLOR_LV_ALTERNATE 可交替设置 Listview 控件与 ListViewItem 项目的背景.
奇数行将获得 GUICtrlSetBkColor 为 Listview 控件设置的颜色.
偶数行将获得 GUICtrlSetBkColor 为 ListviewItem 项目设置的颜色.

相 关 函 数

GUICtrlCreateListView, GUICtrlSetData, GUICtrlSetState, GUICtrlDelete, GUIGetMsg, GUICtrlRead, GUIDataSeparatorChar (Option)

函 数 示 例


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $listview, $button, $item1, $item2, $item3, $msg

    GUICreate("列表视图项目", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF) ; 改变背景颜色

    $listview = GUICtrlCreateListView("列1  |列2|列3  ", 10, 10, 200, 150);,$LVS_SORTDESCENDING)
    $button = GUICtrlCreateButton("选择结果 ?", 75, 170, 70, 20)
    $item1 = GUICtrlCreateListViewItem ("项目 2|列22|列23", $listview)
    $item2 = GUICtrlCreateListViewItem ("............项目 1|列12|列13", $listview)
    $item3 = GUICtrlCreateListViewItem ("项目 3|列32|列33", $listview)
    GUICtrlCreateInput("", 20, 200, 150)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; 允许拖放
    GUISetState()
    GUICtrlSetData($item2, "|项目 1")
    GUICtrlSetData($item3, "||列33")
    GUICtrlDelete($item1)

    Do
        $msg = GUIGetMsg()

        Select
            Case $msg = $button
                MsgBox(0, "列表视图项目 ", GUICtrlRead(GUICtrlRead($listview)), 2)
            Case $msg = $listview
                MsgBox(0, "列表视图", "点击列=" & GUICtrlGetState($listview), 2)
        EndSelect
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

provider with jb51.net (unicode)