基 础 函 数 参 考

GUICtrlCreateRadio

创建单选框(Radio)控件.

GUICtrlCreateRadio ( "文本", 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

文本 控件显示的文本.
左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度 (默认文本自动调整适合宽度).
高度 [可选参数] 控件的高度 (默认文本自动调整适合高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 ( -1) : 无.
强制样式 : $BS_AUTORADIOBUTTON 与 $WS_TABSTOP (若单选框是组的第一个单选框).
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_RADIO, 新样式,...) 语句.

使用上面列出的值必须将 #include <ButtonConstants.au3> 语句写入脚本中.

默认大小 $GUI_DOCKHEIGHT.

相 关 函 数

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $radio1, $radio2, $msg
    GUICreate("我的单选框 GUI") ; 创建居中显示的 GUI 窗口

    $radio1 = GUICtrlCreateRadio("单选框 1", 10, 10, 120, 20)
    $radio2 = GUICtrlCreateRadio("单选框 2", 10, 40, 120, 20)
    GUICtrlSetState($radio2, $GUI_CHECKED)

    GUISetState() ; 显示有复选框控件的 GUI

    ; 运行 GUI, 直到 GUI 被关闭
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $radio1 And BitAND(GUICtrlRead($radio1), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox(64, '信息:', '您点击并选中单选框 1.')
            Case $msg = $radio2 And BitAND(GUICtrlRead($radio2), $GUI_CHECKED) = $GUI_CHECKED
                MsgBox(64, '信息:', '您点击并选中单选框 2.')
        EndSelect
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)