基 础 函 数 参 考

GUICtrlCreateSlider

创建滑动条(Slider)控件.

GUICtrlCreateSlider ( 左距, 顶距 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参 数

左距 控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算左侧位置.
顶距 控件上方的位置. 若此值为 -1, 则根据 GUICoordMode 的设置计算顶部位置.
宽度 [可选参数] 控件的宽度(默认使用先前的宽度).
高度 [可选参数] 控件的高度(默认使用先前的高度).
样式 [可选参数] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 (-1) : $TBS_AUTOTICKS
扩展样式 [可选参数] 控件的扩展样式. 查看附录 扩展样式表.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

要获得控件的值, 查看 GUICtrlRead.
设置或者修改控件信息, 参考 GUICtrlUpdate....

要更新滑动条位置, 使用 GUICtrlSetData.
要设置调节范围的最小/最大值请使用 GUICtrlSetLimit.

要在默认样式上添加新样式, 可使用 BitOr($GUI_SS_DEFAULT_SLIDER, 新样式,...) 语句.

使用上面列出的值必须将 #include <SliderConstants.au3> 语句写入脚本中.

默认大小 $GUI_DOCKAUTO 出现的大小和位置.

相 关 函 数

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $slider1, $button, $msg

    GUICreate("滑动调节器", 220, 100, 100, 200)
    GUISetBkColor(0x00E0FFFF) ; 改变背景颜色

    $slider1 = GUICtrlCreateSlider(10, 10, 200, 20)
    GUICtrlSetLimit(-1, 200, 0) ; 控制最小/最大值
    $button = GUICtrlCreateButton("当前调节值 ?", 75, 70, 80, 20)
    GUISetState()
    GUICtrlSetData($slider1, 45) ; 设置光标

    Do
        $msg = GUIGetMsg()

        If $msg = $button Then
            MsgBox(0, "滑动条", GUICtrlRead($slider1), 2)
        EndIf
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

provider with jb51.net (unicode)