基 础 函 数 参 考

TrayGetMsg

获取托盘事件.

TrayGetMsg ( )

参 数

None.

返 回 值

返回托盘事件.
"事件"返回发送消息的控件 ID, 或者特别事件(如鼠标点击托盘图标). 如没有发生事件, 则事件值为 0.


事件 ID
0 无事件
Control ID 发送消息的控件标识符
$TRAY_EVENT_PRIMARYDOWN 鼠标左键按下
$TRAY_EVENT_PRIMARYUP 鼠标左键释放
$TRAY_EVENT_SECONDARYDOWN 鼠标右键按下
$TRAY_EVENT_SECONDARYUP 鼠标右键释放
$TRAY_EVENT_PRIMARYDOUBLE 鼠标左键双击
$TRAY_EVENT_SECONDARYDOUBLE 鼠标右键双击

备 注

函数自动空闲 CPU, 因此可以安全地用在紧凑循环中, 不会占用所有的 CPU.

上述常数在 #include <Constants.au3> 文件中定义

相 关 函 数

TrayCreateItem, TrayCreateMenu, TrayItemSetOnEvent

函 数 示 例


#NoTrayIcon

Opt("TrayMenuMode", 1) ; 不显示默认菜单(脚本暂停/退出).

Local $settingsitem = TrayCreateMenu("设置")
TrayCreateItem("显示", $settingsitem)
TrayCreateItem("打印", $settingsitem)
TrayCreateItem("")
Local $aboutitem = TrayCreateItem("关于...")
TrayCreateItem("")
Local $exititem = TrayCreateItem("退出")

TraySetState()

While 1
    Local $msg = TrayGetMsg()
    Select
        Case $msg = 0
            ContinueLoop
        Case $msg = $aboutitem
            MsgBox(64, "关于:","AutoIt3-托盘菜单示例")
        Case $msg = $exititem
            ExitLoop
    EndSelect
WEnd

Exit

provider with jb51.net (unicode)