Unity Shader实现新手引导遮罩镂空效果

更新时间：2020年02月13日 09:53:52 作者：mac_zly

这篇文章主要为大家详细介绍了Unity Shader实现新手引导遮罩镂空效果，文中示例代码介绍的非常详细，具有一定的参考价值，感兴趣的小伙伴们可以参考一下

这两天实现了下新手引导需要的遮罩镂空shader效果，记录一下。

1、圆形镂空shader代码：

//计算片元世界坐标和目标中心位置的距离
float dis = distance(IN.worldPosition.xy, _Center.xy);
//过滤掉距离小于（半径-过渡范围）的片元
clip(dis - (_Radius - _TransitionRange));
//优化if条件判断，如果距离小于半径则执行下一步，等于if(dis < _Radius)
fixed tmp = step(dis, _Radius);
//计算过渡范围内的alpha值
color.a *= (1 - tmp) + tmp * (dis - (_Radius - _TransitionRange)) / _TransitionRange;

效果：忽略渐变的蒙版，随便找的图片

2、椭圆镂空shader代码：

//计算X轴方向距离
float disX = distance(IN.worldPosition.x, _Center.x);
//计算Y轴方向距离
float disY = distance(IN.worldPosition.y, _Center.y);
//运用椭圆方程计算片元的alpha值，_Ellipse为椭圆系数
fixed factor = clamp(pow(abs(disX / _Width), _Ellipse) + pow(abs(disY / _Height), _Ellipse), 0.0, 1.0);
//优化if条件判断
fixed tmp = step(factor, 1.0f);
//赋值椭圆外或椭圆内的alpha值
color.a *= (1 - tmp) + tmp * factor;

效果：

3、圆形目标位置聚合动画shader代码：

//_StartTime为效果开始时间点，Unity中对应赋值material.SetFloat("_StartTime", Time.timeSinceLevelLoad);
fixed processTime = _Time.y - _StartTime;
//判断shader执行时长是否超过_TotalTime
clip(_TotalTime - processTime);
//优化if条件判断
fixed tmp = step(processTime, _ReduceTime);
//计算当前时间点的圆形镂空半径
float curRadius = (1 - tmp) * _Radius + tmp * (_MaxRadius - (_MaxRadius - _Radius) * processTime / _ReduceTime);
float dis = distance(IN.worldPosition.xy, _Center.xy);
//抛弃距离小于当前圆形镂空半径的片元
clip(dis - curRadius);

效果：不知道为啥上传上来就有问题了，正常是没问题的

整个shader源码，在Unity UGUI 自带Default shader基础上添加：

// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)

Shader "UI/Default_Mask"
{
  Properties
  {
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)

    _StencilComp ("Stencil Comparison", Float) = 8
    _Stencil ("Stencil ID", Float) = 0
    _StencilOp ("Stencil Operation", Float) = 0
    _StencilWriteMask ("Stencil Write Mask", Float) = 255
    _StencilReadMask ("Stencil Read Mask", Float) = 255

    _ColorMask ("Color Mask", Float) = 15

    [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
 //-------------------add----------------------
 _Center("Center", vector) = (0, 0, 0, 0)
 _Radius("Radius", Range(0,1000)) = 1000 // sliders
 _TransitionRange("Transition Range", Range(0, 100)) = 10
 _Width("Width", Float) = 1
 _Height("Height", Float) = 1
 _Ellipse("Ellipse", Float) = 4
 _ReduceTime("ReduceTime", Float) = 1
 _TotalTime("TotalTime", Float) = 1
 _StartTime("StartTime", Float) = 0
 _MaxRadius("MaxRadius", Float) = 1500
 [KeywordEnum(ROUND, ELLIPSE, DYNAMIC_ROUND)] _RoundMode("Mask mode", Float) = 0
 //-------------------add----------------------
  }

  SubShader
  {
    Tags
    {
      "Queue"="Transparent"
      "IgnoreProjector"="True"
      "RenderType"="Transparent"
      "PreviewType"="Plane"
      "CanUseSpriteAtlas"="True"
    }

    Stencil
    {
      Ref [_Stencil]
      Comp [_StencilComp]
      Pass [_StencilOp]
      ReadMask [_StencilReadMask]
      WriteMask [_StencilWriteMask]
    }

    Cull Off
    Lighting Off
    ZWrite Off
    ZTest [unity_GUIZTestMode]
    Blend SrcAlpha OneMinusSrcAlpha
    ColorMask [_ColorMask]

    Pass
    {
      Name "Default"
    CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #pragma target 2.0

      #include "UnityCG.cginc"
      #include "UnityUI.cginc"

      #pragma multi_compile __ UNITY_UI_CLIP_RECT
      #pragma multi_compile __ UNITY_UI_ALPHACLIP
  #pragma multi_compile _ROUNDMODE_ROUND _ROUNDMODE_ELLIPSE _ROUNDMODE_DYNAMIC_ROUND

      struct appdata_t
      {
        float4 vertex  : POSITION;
        float4 color  : COLOR;
        float2 texcoord : TEXCOORD0;
        UNITY_VERTEX_INPUT_INSTANCE_ID
      };

      struct v2f
      {
        float4 vertex  : SV_POSITION;
        fixed4 color  : COLOR;
        float2 texcoord : TEXCOORD0;
        float4 worldPosition : TEXCOORD1;
        UNITY_VERTEX_OUTPUT_STEREO
      };

      fixed4 _Color;
      fixed4 _TextureSampleAdd;
      float4 _ClipRect;
  //-------------------add----------------------
  half _Radius;
  float2 _Center;
  half _TransitionRange;
  half _Width;
  half _Height;
  half _Ellipse;
  fixed _ReduceTime;
  half _TotalTime;
  float _StartTime;
  half _MaxRadius;

  //-------------------add----------------------

      v2f vert(appdata_t v)
      {
        v2f OUT;
        UNITY_SETUP_INSTANCE_ID(v);
        UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
        OUT.worldPosition = v.vertex;
        OUT.vertex = UnityObjectToClipPos(OUT.worldPosition);

        OUT.texcoord = v.texcoord;

        OUT.color = v.color * _Color;
        return OUT;
      }

      sampler2D _MainTex;

      fixed4 frag(v2f IN) : SV_Target
      {
        half4 color = (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd) * IN.color;

        #ifdef UNITY_UI_CLIP_RECT
        color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
        #endif

        #ifdef UNITY_UI_ALPHACLIP
        clip (color.a - 0.001);
        #endif

  //-------------------add----------------------
#ifdef _ROUNDMODE_ROUND
  //计算片元世界坐标和目标中心位置的距离
  float dis = distance(IN.worldPosition.xy, _Center.xy);
  //过滤掉距离小于（半径-过渡范围）的片元
  clip(dis - (_Radius - _TransitionRange));
  //优化if条件判断，如果距离小于半径则执行下一步，等于if(dis < _Radius)
  fixed tmp = step(dis, _Radius);
  //计算过渡范围内的alpha值
  color.a *= (1 - tmp) + tmp * (dis - (_Radius - _TransitionRange)) / _TransitionRange;
#elif _ROUNDMODE_ELLIPSE
  //计算X轴方向距离
  float disX = distance(IN.worldPosition.x, _Center.x);
  //计算Y轴方向距离
  float disY = distance(IN.worldPosition.y, _Center.y);
  //运用椭圆方程计算片元的alpha值，_Ellipse为椭圆系数
  fixed factor = clamp(pow(abs(disX / _Width), _Ellipse) + pow(abs(disY / _Height), _Ellipse), 0.0, 1.0);
  //优化if条件判断
  fixed tmp = step(factor, 1.0f);
  //赋值椭圆外或椭圆内的alpha值
  color.a *= (1 - tmp) + tmp * factor;
#else
  //_StartTime为效果开始时间点，Unity中对应赋值material.SetFloat("_StartTime", Time.timeSinceLevelLoad);
  fixed processTime = _Time.y - _StartTime;
  //判断shader执行时长是否超过_TotalTime
  clip(_TotalTime - processTime);
  //优化if条件判断
  fixed tmp = step(processTime, _ReduceTime);
  //计算当前时间点的圆形镂空半径
  float curRadius = (1 - tmp) * _Radius + tmp * (_MaxRadius - (_MaxRadius - _Radius) * processTime / _ReduceTime);
  float dis = distance(IN.worldPosition.xy, _Center.xy);
  //抛弃距离小于当前圆形镂空半径的片元
  clip(dis - curRadius);
#endif
  //-------------------add----------------------
        return color;
      }
    ENDCG
    }
  }
}

以上就是本文的全部内容，希望对大家的学习有所帮助，也希望大家多多支持脚本之家。

您可能感兴趣的文章:

C#多线程用法详解
本文详细讲解了C#多线程用法，文中通过示例代码介绍的非常详细。对大家的学习或工作具有一定的参考借鉴价值，需要的朋友可以参考下
2021-12-12
DevExpress SplitContainerControl用法总结
这篇文章主要介绍了DevExpress SplitContainerControl用法,对初学者有一定的参考借鉴价值,需要的朋友可以参考下
2014-08-08
C#实现SSE(Server-Sent Events)服务端和客户端的示例代码
这篇文章主要为大家详细介绍了C#实现SSE(Server-Sent Events)服务端和客户端的相关知识,文中的示例代码讲解详细,有需要的小伙伴可以参考下
2024-03-03
C#知识整理
本文主要介绍了C#的相关知识。具有很好的参考价值，下面跟着小编一起来看下吧
2017-02-02
c# 用Dictionary实现日志数据批量插入
这篇文章主要介绍了c# 用Dictionary实现日志数据批量插入的步骤，帮助大家更好的理解和使用c#中的Dictionary类，感兴趣的朋友可以了解下
2021-02-02
c#使用热键实现程序窗口隐藏示例
下面我们将演示如何通过热键隐藏窗口，会用到DllImports of Win32 API、CallBacks/Delegates，定制事件与事件的句柄,大家参考使用吧友
2014-01-01
C#编程自学之数据类型和变量三
C#语言类型系统提出的一个核心概念装箱（boxing）拆箱（unboxing）。装箱和取消装箱的概念是C#的类型系统的核心。它在“值类型”和“引用类型”之间的架起了一座桥梁，使得任何“值类型”的值都可以转换为object类型的值，反过来转换也可以。
2015-10-10
C#中6种常用集合类小结
这篇文章主要为大家详细介绍了C#中6种常用集合类,文中的示例代码讲解详细,具有一定的借鉴价值,感兴趣的小伙伴可以跟随小编一起学习一下
2024-11-11
C#使用SqlServer作为日志数据库的设计与实现
这篇文章主要给大家介绍了关于C#使用SqlServer作为日志数据库的设计与实现的相关资料，文中通过示例代码介绍的非常详细，对大家的学习或者工作具有一定的参考学习价值，需要的朋友们下面随着小编来一起学习学习吧
2021-01-01
C#实现组合排列的方法
这篇文章主要介绍了C#实现组合排列的方法的相关资料,并附实例代码，需要的朋友可以参考下
2016-10-10

Unity Shader实现新手引导遮罩镂空效果

相关文章

最新评论

大家感兴趣的内容

最近更新的内容

常用在线小工具