一学即会之JDK版本快速切换方法(2024)

@echo off
setlocal

:menu
cls
echo ============================
echo Select the JDK version to use:
echo ============================
echo 1. JDK 8 (C:\Program Files\Java\jdk1.8.0_191)
echo 2. JDK 17 (C:\Program Files\Java\jdk-17)
echo 3. JDK 23 (C:\Program Files\Java\jdk-23)
echo Q. Quit
echo ============================
set /p choice="Enter your choice (1, 2, 3 or Q): "

if /i "%choice%"=="Q" goto :eof

REM 设置 JAVA_HOME 为目标版本对应的路径
if "%choice%"=="1" (
    set "JAVA_HOME=C:\Program Files\Java\jdk1.8.0_191"
) else if "%choice%"=="2" (
    set "JAVA_HOME=C:\Program Files\Java\jdk-17"
) else if "%choice%"=="3" (
    set "JAVA_HOME=C:\Program Files\Java\jdk-23"
) else (
    echo Invalid choice. Please try again.
    pause
    goto :menu
)

REM 验证 JAVA_HOME 是否存在
if not exist "%JAVA_HOME%" (
    echo The specified JDK path does not exist: %JAVA_HOME%
    pause
    exit /b 1
)

REM 更新系统环境变量 JAVA_HOME 和 Path
setx JAVA_HOME "%JAVA_HOME%" /M
REM setx PATH "%JAVA_HOME%\bin;%PATH%" /M

REM 更新当前会话的 JAVA_HOME 和 Path
set "JAVA_HOME=%JAVA_HOME%"
REM set "PATH=%JAVA_HOME%\bin;%PATH%"

echo Switched to JDK %choice%
echo JAVA_HOME is now set to %JAVA_HOME%

pause
endlocal