脚本之家 服务器常用软件
快捷导航
您的位置：首页 → 网站技巧 → 服务器 → nginx → 前端通过nginx访问本地端口

前端如何通过nginx访问本地端口

 更新时间：2025年06月21日 11:01:26   作者：玉笛声声青灵舞  
这篇文章主要介绍了前端如何通过nginx访问本地端口的问题,具有很好的参考价值,希望对大家有所帮助,如有错误或未考虑完全的地方,望不吝赐教

一、nginx安装

1、下载

（1）下载地址

nginx官网

（2）系统选择

1）中“1”为Linux资源，

2）“2”为window资源

（3）版本选择

1）Mainline version 主流版

2）Stable version 稳定版

3）Legacy versions 历史版本

2、安装部署

（1）解压

1）将下载的压缩包解压到指定文件夹

2）文件说明

文件夹说明
confnginx所有的配置文件的目录
contrib存放开源爱好者共享的代码
docs存放文档资料
html默认站点目录,存放了Nginx的错误页面和欢迎页面
logs默认存放访问日志、错误日志和Nginx主进程pid文件
temp临时目录，用于存放Nginx运行时产生的临时文件
nginx.exe可执行程序，常用于Nginx服务的启动、停止等管理工作

（2）配置文件修改

1）在conf目录下找到nginx.conf文件，打开

2）找到server这个节点，视需要修改端口号或默认主页

3）检查修改是否正确

nginx -t -xxxxxx/nginx.conf    // xxxx为nginx.conf所在的绝对路径

4）重启

如果nginx没有启动，则执行启动操作，如果已经启动，执行重启命令

nginx -s reload     // 重启

（3）启动

1）双击nginx.exe（不推荐）

因为直接双击nginx.exe，会导致修改配置后重启、停止nginx无效，需要手动关闭任务管理器内的所有nginx进程。

2）cmd命令启动（推荐）

① 运行cmd打开终端

② 切换磁盘

输入“D:”回车

③ 进入上面解压的文件夹

cd xxxxx    // 目标文件夹路径

或者直接在解压文件夹中右键 => 在终端中打开，直接进入此路径

④ 启动——执行命令后会有窗口一闪而过

start nginx

⑤ 检查是否启动成功

通过命令确认：

tasklist /fi "imagename eq nginx.exe"

通过任务管理器确认：

通过命令启动nginx时，其进程在详细信息中展现，通过双击nginx.exe启动的进程才在进程栏中展现。

⑥ 访问端口

打开浏览器，访问http://localhost:80或127.0.0.1:80，页面出现以下内容

（4）nginx脚本创建

上面已经阐述了为什么要使用cmd命令来管理nginx，但如果需要经常使用的话就比较麻烦了，所以就需要一个脚本来提升我们的管理效率。

1）创建txt文档；

2）脚本代码

@echo off
rem 提供Windows下nginx的启动，重启，关闭功能
echo ==================begin========================
cls 
::ngxin 所在的盘符
set NGINX_PATH=E:
::nginx 所在目录
set NGINX_DIR=E:\develop\nginx-1.10.1\
color 0a 
TITLE Nginx 管理程序增强版
CLS 
echo. 
echo. ** Nginx 管理程序  *** 
echo. *** create 2017-09-22 *** 
echo. 
:MENU 
echo. ***** nginx 进程list ****** 
::tasklist|findstr /i "nginx.exe"
tasklist /fi "imagename eq nginx.exe"
echo. 
    if ERRORLEVEL 1 (
        echo nginx.exe不存在
    ) else (
        echo nginx.exe存在
    )
echo. 
::*************************************************************************************************************
echo. 
	echo.  [1] 启动Nginx  
	echo.  [2] 关闭Nginx  
	echo.  [3] 重启Nginx 
	echo.  [4] 刷新控制台  
	echo.  [5] 重新加载Nginx配置文件
	echo.  [6] 检查测试nginx配置文件
	echo.  [7] 查看nginx version
	echo.  [0] 退 出 
echo. 
echo.请输入选择的序号:
set /p ID=
	IF "%id%"=="1" GOTO start 
	IF "%id%"=="2" GOTO stop 
	IF "%id%"=="3" GOTO restart 
	IF "%id%"=="4" GOTO MENU
	IF "%id%"=="5" GOTO reloadConf 
	IF "%id%"=="6" GOTO checkConf 
	IF "%id%"=="7" GOTO showVersion 
	IF "%id%"=="0" EXIT
PAUSE 
::*************************************************************************************************************
::启动
:start 
	call :startNginx
	GOTO MENU
::停止
:stop 
	call :shutdownNginx
	GOTO MENU
::重启
:restart 
	call :shutdownNginx
	call :startNginx
	GOTO MENU
::检查测试配置文件
:checkConf 
	call :checkConfNginx
	GOTO MENU
::重新加载Nginx配置文件
:reloadConf 
    call :checkConfNginx
	call :reloadConfNginx
	GOTO MENU
::显示nginx版本
:showVersion 
    call :showVersionNginx
	GOTO MENU	
::*************************************************************************************
::底层
::*************************************************************************************
:shutdownNginx
	echo. 
	echo.关闭Nginx...... 
	taskkill /F /IM nginx.exe > nul
	echo.OK,关闭所有nginx 进程
	goto :eof
:startNginx
	echo. 
	echo.启动Nginx...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )
	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
 
	IF EXIST "%NGINX_DIR%nginx.exe" (
		echo "start '' nginx.exe"
		start "" nginx.exe
	)
	echo.OK
	goto :eof
:checkConfNginx
	echo. 
	echo.检查测试 nginx 配置文件...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )
	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
	nginx -t -c conf/nginx.conf
	goto :eof
::重新加载 nginx 配置文件
:reloadConfNginx
	echo. 
	echo.重新加载 nginx 配置文件...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )
	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
	nginx -s reload
	goto :eof
::显示nginx版本
:showVersionNginx
	echo. 
	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
	nginx -V
 	goto :eof

3）另存

注意

① 文件名保存为.bat类型

② 编码格式建议选择ANSI，防止中文乱码

③ 另存地址与nginx.exe同级

4）双击执行

① 1处为双击后打开窗口的显示内容

② 2处为需要执行的命令的序号，如需要启动，就输入1然后回车

5）快捷方式

因为脚本文件时保存在nginx文件夹下，每次需要使用的时候都需要先进入nginx文件夹，比较麻烦，所以直接创建快捷方式放在桌面。

① 右键脚本选择“创建快捷方式”

② 将快捷方式剪切到桌面上。如果觉得这个快捷方式难看，就继续往下看

③ 右键快捷方式选择属性

④ 点击更改图标，可以使用系统内置的图标，也可以使用自定义图标

⑤ 自定义图标

图标格式要求为.icon、.dll、.icl格式，准备好图标之后选择应用即可，可以先用jpg等格式的图片进行转换

二、使用

其他命令

// 结束进程
nginx -s stop    // 快速结束
nginx -s quit    // 完整有序的结束

// 重新加载
nginx -s reload

总结

以上为个人经验，希望能给大家一个参考，也希望大家多多支持脚本之家。

您可能感兴趣的文章:

相关文章

  • 如何使用Nginx解决跨域问题详解

    如何使用Nginx解决跨域问题详解

    本地运行一个项目,但是要访问外域的api接口,存在跨域问题,下面这篇文章主要给大家介绍了关于如何使用Nginx解决跨域问题的相关资料,文中介绍的非常详细,需要的朋友可以参考下
    2022-05-05
  • nginx校验指定conf文件是否正确的方法

    nginx校验指定conf文件是否正确的方法

    校验 Nginx 指定配置文件的语法是否正确,是保证 Nginx 服务稳定运行的关键一步,可以使用 Nginx 内置的 -t 测试参数,配合 -c 参数来指定配置文件,下面小编给大家详细介绍一下,需要的朋友可以参考下
    2025-08-08
  • 教你如何快速搭建和配置 Nginx 服务器

    教你如何快速搭建和配置 Nginx 服务器

    Nginx 是一个高性能的 HTTP 和反向代理服务器,也是一个 IMAP/POP3/SMTP 代理服务器,本文将详细介绍如何在 Linux 上安装、配置和管理 Nginx 服务器,感兴趣的朋友一起看看吧
    2024-07-07
  • Nginx配置中使用Lua脚本的实现步骤

    Nginx配置中使用Lua脚本的实现步骤

    在阿里云API网关和字节跳动边缘计算平台中,Nginx+Lua的组合已成为处理复杂业务逻辑的标准解决方案,下面我们就来介绍一下Nginx配置中使用Lua脚本的实现步骤,感兴趣都可以了解一下
    2025-09-09
  • 使用Nginx解决跨域访问问题的完整案例

    使用Nginx解决跨域访问问题的完整案例

    在现代的Web开发中,跨域访问是一种常见的需求,由于浏览器的同源策略,不同域名之间的访问存在一定的限制,本文将介绍如何使用Nginx来解决跨域访问的问题,并通过一个完整的实例来展示,需要的朋友可以参考下
    2024-03-03
  • Nginx中root与alias区别讲解

    Nginx中root与alias区别讲解

    这篇文章主要介绍了Nginx中root与alias区别 ,通过两个小例子来学习root和alias的区别，对Nginx中root与alias区别感兴趣的朋友跟随小编一起看看吧
    2022-08-08
  • 详解如何修改nginx的默认端口

    详解如何修改nginx的默认端口

    这篇文章主要介绍了详解如何修改nginx的默认端口，文中通过示例代码介绍的非常详细，对大家的学习或者工作具有一定的参考学习价值，需要的朋友们下面随着小编来一起学习学习吧
    2021-03-03
  • nginx配置引发的403问题解决办法

    nginx配置引发的403问题解决办法

    这篇文章主要介绍了nginx配置引发的403问题解决办法的相关资料,需要的朋友可以参考下
    2017-06-06
  • Nginx服务器作反向代理实现内部局域网的url转发配置

    Nginx服务器作反向代理实现内部局域网的url转发配置

    这篇文章主要介绍了Nginx服务器作反向代理实现内部局域网的url转发实例,文中提到需要注意proxy_read_timeout参数的相关调整,需要的朋友可以参考下
    2016-01-01
  • django8.5 项目部署Nginx的操作步骤

    django8.5 项目部署Nginx的操作步骤

    nginx是一个开源的，支持高性能，高并发的www服务和代理服务软件。它是一个俄罗斯人lgor sysoev开发的，作者将源代码开源出来供全球使用，下面小编给大家带来了django8.5 项目部署Nginx的操作步骤，感兴趣的朋友一起看看吧
    2022-01-01

最新评论