基 础 函 数 参 考

GUICtrlCreateTabItem

创建标签选项页(TabItem)控件.

GUICtrlCreateTabItem ( "文本" )

参 数

文本 控件显示的文本.

返 回 值

成功: 返回控件标识符(控件ID).
失败: 返回 0.

备 注

使用 GUICtrlUpdate... 设置其它信息.

要让指定标签选项页优先显示, 使用 GUICtrlSetState(-1,$GUI_SHOW) 语句. 参考例子.

要结束标签控件定义, 则设置最后一个标签选项页为空文本即可. 这个标签选项页将不被绘制 (代码太多了 ...).

当使用高级模式, GUICtrlRead($tab,1) 将返回控件 ID, 而不是标签选项页的索引.

要创建新控件到现有标签选项页上, 使用 GUISwitch($hWin,$tabitem).
不要忘记使用 GUICtrlCreateTabItem("") 语句结束标签选项页的创建.

相 关 函 数

GUICtrlSetState, GUISwitch, GUIGetMsg, GUICtrlRead, GUIEventOptions (Option), GUICtrlCreateTab

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $tab
    Local $msg

    GUICreate("我的标签选项卡 GUI", 300, 150); 创建居中显示的 GUI 窗口

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    $tab = GUICtrlCreateTab(10, 10, 200, 100)

    GUICtrlCreateTabItem ("标签 0")
    GUICtrlCreateLabel("标记0", 30, 80, 50, 20)
    GUICtrlCreateButton("确定0", 20, 50, 50, 20)
    GUICtrlCreateInput("默认项", 80, 50, 70, 20)

    GUICtrlCreateTabItem ("标签 ----1")
    GUICtrlCreateLabel("标记1", 30, 80, 50, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "资源|数码弹头|拉里|乔恩|泰罗", "乔恩"); 默认乔恩
    GUICtrlCreateButton("确定1", 80, 50, 50, 20)

    GUICtrlCreateTabItem ("标签 2")
    GUICtrlSetState(-1, $GUI_SHOW); "默认项"
    GUICtrlCreateLabel("标记2", 30, 80, 50, 20)
    GUICtrlCreateButton("确定2", 140, 50, 50)

    GUICtrlCreateTabItem (""); 结束选项卡项目定义

    GUICtrlCreateLabel("点击选项卡, 看窗口标题", 20, 130, 250, 20)

    GUISetState()

    ; 运行 GUI, 直到 GUI 被关闭
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        If $msg = $tab Then
            ; 显示点击的选项卡
            WinSetTitle("我的标签选项卡 GUI", "", "我的标签选项卡 GUI + " & GUICtrlRead($tab))
        EndIf
    WEnd
EndFunc   ;==>Example

provider with jb51.net (unicode)