基 础 函 数 参 考

GUISwitch

切换 GUI 函数的当前窗口.

GUISwitch ( 句柄 [, 标签项目ID] )

参 数

句柄 切换为当前窗口的句柄.
标签项目ID [可选参数] 被选中标签项目的控件标识符.

返 回 值

成功: 返回上一个"当前"窗口的句柄.
失败: 返回空句柄.

备 注

许多 GUI 函数都是把"当前"窗口作为工作窗口 - "当前"窗口通常指 GUICreate 创建的最后一个窗口.
本函数能够指定其它窗口成为"当前"窗口. 但这并不意味着引用窗口将被激活. 要激活窗口必须调用 WinActivate.

使用"标签项目ID"允许创建一个新控件到指定的标签项目控件中.
不要忘记使用 GuiCtrlCreateTabItem("") 关闭标签项目定义

相 关 函 数

GUICreate, GUIDelete, GUICtrlCreateTabItem

函 数 示 例


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $parent1, $parent2, $TabItem , $msg

    $parent1 = GUICreate("父窗 1")
    GUICtrlCreateTab(10, 10)
    $TabItem  = GUICtrlCreateTabItem ("标签 1")
    GUICtrlCreateTabItem ("标签 2")
    GUICtrlCreateTabItem ("")

    $parent2 = GUICreate("父窗 2", -1, -1, 100, 100)

    GUISwitch($parent2)
    GUISetState()
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE

    GUISwitch($parent1, $TabItem )
    GUICtrlCreateButton("确定", 50, 50, 50)
    GUICtrlCreateTabItem ("")

    GUISetState(@SW_SHOW, $parent1)
    Do
        $msg = GUIGetMsg()
    Until $msg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

provider with jb51.net (unicode)